{
  description = "HROB 2022 Website";

  inputs = {
    flake-compat = {
      url = "github:edolstra/flake-compat";
      flake = false;
    };

    hakyll-contrib-tojnar.url = "gitlab:tojnar.cz/hakyll-contrib-tojnar";

    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, flake-compat, hakyll-contrib-tojnar, nixpkgs, utils }:
    utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        haskellPackages = pkgs.haskellPackages.override {
          overrides = final: prev: {
            hrob2022-krk-litvinov-cz = final.callPackage ./hrob2022-krk-litvinov-cz.nix { };
          } // hakyll-contrib-tojnar.haskellOverlay final prev;
        };

      in {
        devShells = {
          default = pkgs.mkShell {
            buildInputs = [
              self.packages.${system}.default
            ];
          };

          haskell = self.packages.${system}.hrob2022-krk-litvinov-cz.env.overrideAttrs (attrs: {
            nativeBuildInputs = attrs.nativeBuildInputs ++ [
              pkgs.cabal-install
            ];
          });
        };

        packages = rec {
          hrob2022-krk-litvinov-cz = haskellPackages.hrob2022-krk-litvinov-cz;

          default = hrob2022-krk-litvinov-cz;
        };

        apps = rec {
          hrob2022-krk-litvinov-cz = utils.lib.mkApp {
            drv = self.packages.${system}.hrob2022-krk-litvinov-cz;
          };

          default = hrob2022-krk-litvinov-cz;
        };
      }
  );
}